Forget-Me-Not

//----------------------------
// Forget-Me-Not
//
// by Elie Zananiri & HyeJin Yoo
// based on code from Making Things Talk by Tom Igoe
 
//----------------------------
#define SOUND1    4
#define SOUND2    5
#define SOUND3    6
 
#define MONITOR   13
 
#define THRESHOLD 79
#define MSGLENGTH 22
#define INTERVAL  30000
 
//----------------------------
int packet[MSGLENGTH];
int byteCounter;
 
long lastPlayedSound1 = 0;
long lastPlayedSound2 = 0;
long lastPlayedSound3 = 0;
 
int address = 0;
int rssi = 0;
 
//----------------------------
void setup() {
  // open the serial port
  Serial.begin(9600);
 
  // configure output pins
  pinMode(SOUND1, OUTPUT);
  pinMode(SOUND2, OUTPUT);
  pinMode(SOUND3, OUTPUT);
}
 
//----------------------------
void loop() {
  // check for any messages and read up to 2 packets at a time
  int readCount = 0;
  while (Serial.available() > 0 && readCount < (MSGLENGTH*2)) {
    handleIncoming();
    readCount++;
    delay(5);
  }
 
  // flash the monitor pin to let us know all is working
  digitalWrite(MONITOR, HIGH);
  delay(50);
  digitalWrite(MONITOR, LOW);
  delay(50);
}
 
//----------------------------
void handleIncoming() {
  // read a byte from the port
  int b = Serial.read();
  // if this is a start byte, it's a new packet
  if (b == 0x7E) {
    // if there is data, parse the previous packet
    if (packet[2] > 0) {
      parseData();
    }
 
    // reset the byte counter
    byteCounter = 0;
  }
 
  // store the current byte into the packet
  packet[byteCounter] = b;
  byteCounter++;
}
 
//----------------------------
void parseData() {
  // read the address, which is a two-byte value
  address = packet[5] + packet[4]*256;
 
  // read the signal strength
  rssi = packet[6];
 
  // get the time
  long now = millis();
 
  // trigger a sound if the signal is not strong enough
  // and the sound has not played in a while
  if (address == 0x1ABC && rssi > THRESHOLD) {
    if (now - lastPlayedSound1 > INTERVAL) {
      lastPlayedSound1 = now;
      playSound(SOUND1);
    }
  }
  else if (address == 0x1CBA && rssi > THRESHOLD) {
    if (now - lastPlayedSound2 > INTERVAL) {
      lastPlayedSound2 = now;
      playSound(SOUND2);
    }
  }
  else if (address == 0x1BBB && rssi > THRESHOLD) {
   if (now - lastPlayedSound3 > INTERVAL) {
     lastPlayedSound3 = now;
     playSound(SOUND3);
   }
  }
}
 
//----------------------------
void playSound(int sound) {
  digitalWrite(sound, HIGH);
  delay(100);
  digitalWrite(sound, LOW);
  delay(6*1000);  // enough time to play the entire sample
 
  // flush the serial buffer to ignore all backed up messages
  Serial.flush();
}